wiimote + motiondive .tokyo

普段はVJのプレイ時に、motion dive.tokyoてソフトを使ってます。

あまりwiiで操作するのに向いてるソフトではありませんが、とりあえずwii + GlovePIEでmotion diveを操作するときのスクリプトを書いたんで載せときます。

mdt、キーボードショートカットを割り当てられる要素が少ないんで、正味wiiでもあまり割り当てる機能がないです（笑）

それでもやっぱPCの前につきっきりでなくVJできるってのは魅力的！

もしこの記事見てピンと来るようなマニアックな方で、こうしたら？ってのあったらアドヴァイスをいただければ・・◎

※ちなみにmdtのほかにはresolumeも使います。あとfireflyは使いづらい。

キー割り当ては、

• wii A : ABスイッチ
• wii B : ブルブルします（笑
• wii Home : ブレイクダウン（暗転）
• wii - : Bデッキにsub1を選択
• wii + : Bデッキにsub2を選択
• wii 1 : Aデッキをスクラッチ
• wii 2 : Bデッキをスクラッチ

• Nunchuk C : Aデッキにsub1を選択
• Nunchuk Z : Bデッキにsub1を選択
• Nunchuk スティックX方向 : ABデッキをフェード

あとはリモコンのx軸方向への傾きによってLEDのイルミネーションが変化します。

ほんとは何か押しながら、リモコンを振ったら色が変わるとかやりたいんだけどな。。この辺fireflyだと簡単っぽい。

あとはmdt.consoleのMIDIインタフェースに内部的にアクセスできるなら、GlovePIE経由でMIDI渡して複雑なこともできる予感。

コードは以下の感じ。

主にAB両デッキのsub1,sub2にも映像を設定しておいて、右手でリモコンの+-、左手でヌンチャクのczを押しつつ、リモコンのAでABデッキ切り替え、のような使い方を想定。一応これで映像６パターンを自由に入れ替えられるはず。

/*********************************
WiiRemote + MDT script v0.3
(c)joe mio  jmworks.co.uk
jmworks@gmail.com

Some Inspiration from
WiiRemoteVJ solution script v0.2b
http://www.htmk.net/weblog/2007/06/how_to_wiimotevj_with_firefly.php
**********************************/

//For Default MDT ShortCuts

////sendkey
Up = Wiimote.Up
Down = Wiimote.Down
Left = Wiimote.Left
Right = Wiimote.Right

//Change Source (sub1, sub2)
//A
if(wiimote.Nunchuk.Cbutton) then
	Z = true
	Shift = true
	wait 1 ms
	Z = false
	Shift = false
endif
if(wiimote.Nunchuk.Zbutton) then
	X = true
	Shift = true
	wait 1 ms
	X = false
	Shift = false
endif
//B 
Z = Wiimote.Minus or Wiimote.Classic.Minus
X = Wiimote.Plus or Wiimote.Classic.Plus

//Switch a-b
Space = Wiimote.A

//Scratch
//A
if(Wiimote.1) then
	BackSpace = true
	Shift = true
	wait 1 ms
	BackSpace = false
	Shift = false
endif
//B
if(Wiimote.2) then
	BackSpace = true
	wait 1 ms
	BackSpace = false
endif


//Breakdown
Key.Escape = Wiimote1.Home

//Rumble
if (wiimote.A) then
   wiimote.Rumble = 5
   wait 1 ms
   wiimote.Rumble = 0
endif
if (wiimote.B) then
   wiimote.Rumble = 5
   wait 1 ms
   wiimote.Rumble = 0
endif

//Fade A/B with Nunchuk
if(Wiimote.Nunchuk.JoyX < -0.25)then
	Ctrl = true
	Left = true
	wait 1ms
	Ctrl = false
	Left = false
endif
if(Wiimote.Nunchuk.JoyX > 0.25)then
	Ctrl = true
	Right = true
	wait 1ms
	Ctrl = false
	Right = false
endif


//revise gravity
var.xdefault = -1
var.xRot = Wiimote.RawForceX + var.xdefault

//LED illumination
if (var.xRot > 8) then
	wiimote.led1 = true
	wiimote.led2 = true
	wiimote.led3 = false
	wiimote.led4 = false
endif
if (var.xRot > 18) then
	wiimote.led1 = true
	wiimote.led2 = false
	wiimote.led3 = false
	wiimote.led4 = false
endif
if (var.xRot < -8) then
	wiimote.led1 = false
	wiimote.led2 = false
	wiimote.led3 = true
	wiimote.led4 = true
endif
if (var.xRot < -18) then
	wiimote.led1 = false
	wiimote.led2 = false
	wiimote.led3 = false
	wiimote.led4 = true
endif
if (var.xRot <= 15 and var.xRot >= -15)then
	Wiimote.led1 = false
	wiimote.led2 = true
	wiimote.led3 = true
	wiimote.led4 = false
endif